home *** CD-ROM | disk | FTP | other *** search
/ PC World Komputer 2010 April / PCWorld0410.iso / hity wydania / Ubuntu 9.10 PL / karmelkowy-koliberek-desktop-9.10-i386-PL.iso / casper / filesystem.squashfs / usr / lib / perl5 / Gtk2 / TestHelper.pm < prev   
Encoding:
Perl POD Document  |  2009-05-17  |  5.3 KB  |  242 lines
  1. #
  2. # $Id$
  3. #
  4.  
  5. package Gtk2::TestHelper;
  6. use strict;
  7. use warnings;
  8. use Test::More;
  9. use Carp;
  10.  
  11. our $VERSION = '0.02';
  12.  
  13. sub import
  14. {
  15.     shift;
  16.     my %opts = (@_);
  17.  
  18.     plan skip_all => $opts{skip_all} if ($opts{skip_all});
  19.  
  20.     croak "tests must be provided at import" unless (exists ($opts{tests}));
  21.  
  22.     if ($opts{nowin32} && $^O eq 'MSWin32')
  23.     {
  24.         plan skip_all => "not appliciable on win32";
  25.     }
  26.  
  27.     if ($opts{at_least_version})
  28.     {
  29.         my ($rmajor, $rminor, $rmicro, $text) = 
  30.                         @{$opts{at_least_version}};
  31.         unless (Gtk2->CHECK_VERSION ($rmajor, $rminor, $rmicro))
  32.         {
  33.             plan skip_all => $text;
  34.         }
  35.     }
  36.  
  37.     # gtk+ 2.0.x can use X fonts, and requires a connection to the
  38.     # display at all times; so, ignore noinit for those versions.
  39.     delete $opts{noinit} unless Gtk2->CHECK_VERSION (2, 2, 0);
  40.  
  41.     if( $opts{noinit} || Gtk2->init_check )
  42.     {
  43.         plan tests => $opts{tests};
  44.     }    
  45.     else
  46.     {    
  47.         plan skip_all => 'Gtk2->init_check failed, probably '
  48.                 .'unable to open DISPLAY';
  49.     }
  50.  
  51.     # ignore keyboard
  52.     Gtk2->key_snooper_install (sub { 1; });
  53.  
  54.     # turn on strict and warnings in caller
  55.     $^W = 1;
  56.     @_ = ();
  57.     goto &strict::import;
  58. }
  59.  
  60. package main;
  61.  
  62. # go ahead and use Gtk2 for them.
  63. use Gtk2;
  64. # and obviously they'll need Test::More
  65. use Test::More;
  66.  
  67. # encourage use of these constants in tests
  68. use Glib qw(TRUE FALSE);
  69.  
  70.  
  71. # useful wrappers
  72. sub run_main (;&) {
  73.     my $callback = shift;
  74.     Glib::Idle->add (sub {
  75.         if ($callback) {
  76.             #print "# Entering run_main shutdown callback\n";
  77.             $callback->();
  78.             #print "# Leaving run_main shutdown callback\n";
  79.         }
  80.         Gtk2->main_quit;
  81.         FALSE;
  82.     });
  83.     #print "# Entering main loop (run_main)\n";
  84.     Gtk2->main;
  85.     #print "# Leaving main loop (run_main)\n";
  86. }
  87. sub ok_idle ($;$) {
  88.     my ($testsub, $test_name) = @_;
  89.     run_main {
  90.         # 0 Test::More::ok
  91.         # 1 this block's ok() call
  92.         # 2 idle callback in run_main
  93.         # 3 Gtk2::main call in run_main
  94.         # 4 Gtk2::main call in run_main (again)
  95.         # 5 ok_idle
  96.         # 6 the caller we want to print
  97.         local $Test::Builder::Level = 6;
  98.         ok ($testsub->(), $test_name);
  99.     }
  100. }
  101. sub is_idle ($$;$) {
  102.     my ($asub, $b, $test_name) = @_;
  103.     run_main {
  104.         local $Test::Builder::Level = 6; # see ok_idle()
  105.         is ($asub->(), $b, $test_name);
  106.     }
  107. }
  108.  
  109.  
  110. sub ginterfaces_ok {
  111.     my ($object_or_package) = @_;
  112.     my $type = ref $object_or_package || $object_or_package;
  113.     my $i = 0;
  114.     my @ifaces = Glib::Type->list_interfaces ($type);
  115.     foreach my $iface (@ifaces) {
  116.         if ($object_or_package->isa ($iface)) {
  117.             $i++;
  118.         } else {
  119.             warn "GType $type is supposed to implement $iface, "
  120.                . "but \@type\::ISA doesn't contain $iface!\n";
  121.         }
  122.     }
  123.     is ($i, scalar(@ifaces), "GInterface versus \@ISA for $type");
  124. }
  125.  
  126.  
  127. # Inspired by Test::Number::Delta
  128. sub delta_ok ($$;$) {
  129.     my ($a, $b, $msg) = @_;
  130.     ok (abs ($a - $b) < 1e-6, $msg);
  131. }
  132.  
  133.  
  134. 1;
  135. __END__
  136.  
  137. =head1 NAME
  138.  
  139. Gtk2::TestHelper - Code to make testing Gtk2 and friends simpler.
  140.  
  141. =head1 SYNOPSIS
  142.  
  143.   use Gtk2::TestHelper tests => 10;
  144.  
  145. =head1 DESCRIPTION
  146.  
  147. A simplistic module that brings together code that would otherwise have to be
  148. copied into each and every test. The magic happens during the importing process
  149. and therefore all options are passed to the use call. The module also use's
  150. strict, warnings, Gtk2, and Test::More so that the individual tests will not
  151. have to. The only required option is the number of tests. The module installs a
  152. key snooper that causes all keyboard input to be ignored.
  153.  
  154. =head1 OPTIONS
  155.  
  156. =over
  157.  
  158. =item tests
  159.  
  160. The number of tests to be completed.
  161.  
  162. =item noinit
  163.  
  164. Do not call Gtk2->init_check, assume that it is not necessary.
  165.  
  166. =item nowin32
  167.  
  168. Set to true if all tests are to be skipped on the win32 platform.
  169.  
  170. =item at_least_version
  171.  
  172. A reference to a list that is checked with Gtk2->CHECK_VERSION.
  173.  
  174. =item skip_all
  175.  
  176. Simply skip all tests with the reason provided.
  177.  
  178. =back
  179.  
  180. =head1 "EXPORTED" FUNCTIONS
  181.  
  182. This module also defines a few utility functions for use in tests; since
  183. we already override import and pull the dirty trick of calling use in
  184. the package main, these are defined in the package main rather than exported
  185. by Exporter.
  186.  
  187. =over
  188.  
  189. =item run_main
  190.  
  191. =item run_main (CODEREF)
  192.  
  193. =item run_main BLOCK
  194.  
  195. Run a main loop, and stop when all pending events are handled.  This is
  196. useful if you have a test that needs a main loop to run properly, because
  197. it allows your program to remain noninteractive.  Important for a test
  198. suite.
  199.  
  200. If the optional I<CODEREF> is supplied, it will be run right before killing
  201. the mainloop.  The function is prototyped to allow two styles of invocation:
  202.  
  203.   run_main (\&some_sub);    # explicit code reference
  204.   run_main { print "hi" };  # callback as a block
  205.  
  206. =item ok_idle (TEST_SUB [, TEST_NAME])
  207.  
  208. Run Test::Simple's ok() on the return value of I<TEST_SUB> after handling
  209. pending events.  Implemented with C<run_main> and other special trickery.
  210.  
  211. =item is_idle (THIS_SUB, THAT [, NAME])
  212.  
  213. Like ok_idle(), but compares the return value of I<THIS_SUB> with I<THAT>
  214. using Test::More's is().
  215.  
  216. =item ginterfaces_ok (GOBJECT_OR_PACKAGE)
  217.  
  218. Verify that the GObject subclass I<GOBJECT_OR_PACKAGE>'s @ISA is set up properly
  219. with all of the GInterfaces that the type system claims it supports.  Something
  220. like an isa_ok() in steroids.
  221.  
  222. =item delta_ok (A, B [, NAME])
  223.  
  224. Checks that the absolute difference of the numbers A and B is smaller than
  225. 1e-6.
  226.  
  227. =back
  228.  
  229. =head1 SEE ALSO
  230.  
  231. L<perl>(1), L<Gtk2>(3pm).
  232.  
  233. =head1 AUTHORS
  234.  
  235. The Gtk2-Perl Team.
  236.  
  237. =head1 COPYRIGHT AND LICENSE
  238.  
  239. Copyright 2003-2005 by the gtk2-perl team.
  240.  
  241. LGPL, See LICENSE file for more information.
  242.